@echo off
chcp 65001 >nul
setlocal enabledelayedexpansion

:: PowerShellを使って今日の日付を正確に取得（YYYYMMDD形式 および MMDD形式）
for /f "usebackq" %%I in (`powershell -NoProfile -Command "Get-Date -Format 'yyyyMMdd'"`) do set yyyymmdd=%%I
for /f "usebackq" %%I in (`powershell -NoProfile -Command "Get-Date -Format 'MMdd'"`) do set mmdd=%%I

echo.
echo 0: mmdd (日付のみ)
echo 1: mmdd_F3
echo 2: yyyymmdd_F3_後続
echo 3: yyyymmdd_ExchangeAdonError
echo 4: yyyymmdd (日付のみ)
echo 5: yyyymmdd_del
echo 6: yyyymmdd_recover
echo 7: yyyymmdd (姓名・ドメイン変更)
echo 8: yyyymmdd_GroupLicense
echo.
set /p choice=番号を選択してください:

set "folder_name="
if "!choice!"=="0" set "folder_name=!mmdd!"
if "!choice!"=="1" set "folder_name=!mmdd!_F3"
if "!choice!"=="2" set "folder_name=!yyyymmdd!_F3_後続"
if "!choice!"=="3" set "folder_name=!yyyymmdd!_ExchangeAdonError"
if "!choice!"=="4" set "folder_name=!yyyymmdd!"
if "!choice!"=="5" set "folder_name=!yyyymmdd!_削除"
if "!choice!"=="6" set "folder_name=!yyyymmdd!_復元"
if "!choice!"=="7" set "folder_name=!yyyymmdd!"
if "!choice!"=="8" set "folder_name=!yyyymmdd!_グループライセンスの手動設定"

if "!folder_name!"=="" (
    echo 無効な選択です。
    exit /b
)

set "final_folder=!folder_name!"
set count=1
:check_folder
if exist "!final_folder!" (
    set "final_folder=!folder_name!ver!count!"
    set /a count+=1
    goto check_folder
)

mkdir "!final_folder!"
echo フォルダ "!final_folder!" を作成しました。

:: 追加処理: 1 が選択された場合、「ツール」フォルダをコピー
if "!choice!"=="1" if exist "ツール" (
    xcopy /E /I /Q "ツール" "!final_folder!"
    echo "ツール" フォルダの内容をコピーしました。
)

:: 追加処理: 2 が選択された場合、「【ツール】PCセキュリティ後継処理CSV生成v1.xlsm」をコピー
if "!choice!"=="2" if exist "ツール\basefile\【ツール】PCセキュリティ後継処理CSV生成v1.xlsm" (
    xcopy /Y "ツール\basefile\【ツール】PCセキュリティ後継処理CSV生成v1.xlsm" "!final_folder!\"
    echo "【ツール】PCセキュリティ後継処理CSV生成v1.xlsm" をコピーしました。
) else (
    echo [警告] "ツール\basefile\【ツール】PCセキュリティ後継処理CSV生成v1.xlsm" が見つかりません。
)

if "!choice!"=="0" if exist "ツール" (
    xcopy /E /I /Q "ツール" "!final_folder!"
    echo "ツール" フォルダの内容をコピーしました。
)

if "!choice!"=="7" (
    if exist "yyyymmdd_フォーマット" (
        if exist "yyyymmdd_フォーマット\sql払出_改修.xlsm" (
            xcopy /Y "yyyymmdd_フォーマット\sql払出_改修.xlsm" "!final_folder!\"
            echo "sql払出_改修.xlsm" をコピーしました。
        ) else (
            echo [警告] "sql払出_改修.xlsm" が見つかりません。
        )
        if exist "yyyymmdd_フォーマット\証跡" (
            xcopy /E /I /Q /Y "yyyymmdd_フォーマット\証跡" "!final_folder!\証跡"
            echo "証跡" フォルダの内容をコピーしました。
        ) else (
            echo [警告] "証跡" フォルダが見つかりません。
        )
    ) else (
        echo [エラー] "yyyymmdd_フォーマット" フォルダが見つかりません。
    )
)

echo 完了しました。
exit /b